mirror of
https://github.com/logseq/logseq.git
synced 2026-04-28 08:04:40 +00:00
3fe790d4d7
This allows for easier use of debugging graphs as they are exported by users as a file. Also DRYed up duplicated helper
57 lines
2.2 KiB
Clojure
57 lines
2.2 KiB
Clojure
(ns export-graph
|
|
"A script that exports a graph to a sqlite.build EDN file"
|
|
(:require ["fs" :as fs]
|
|
["path" :as node-path]
|
|
[babashka.cli :as cli]
|
|
[clojure.pprint :as pprint]
|
|
[logseq.db.common.sqlite-cli :as sqlite-cli]
|
|
[logseq.db.sqlite.export :as sqlite-export]
|
|
[nbb.core :as nbb]))
|
|
|
|
(defn- resolve-path
|
|
"If relative path, resolve with $ORIGINAL_PWD"
|
|
[path]
|
|
(if (node-path/isAbsolute path)
|
|
path
|
|
(node-path/join (or js/process.env.ORIGINAL_PWD ".") path)))
|
|
|
|
(def spec
|
|
"Options spec"
|
|
{:help {:alias :h
|
|
:desc "Print help"}
|
|
:include-timestamps? {:alias :t
|
|
:desc "Include timestamps in export"}
|
|
:file {:alias :f
|
|
:desc "Saves edn to file"}
|
|
:catch-validation-errors? {:alias :c
|
|
:desc "Catch validation errors for dev"}
|
|
:exclude-namespaces {:alias :e
|
|
:coerce #{}
|
|
:desc "Namespaces to exclude from properties and classes"}
|
|
:exclude-built-in-pages? {:alias :b
|
|
:desc "Exclude built-in pages"}
|
|
:exclude-files? {:alias :F
|
|
:desc "Exclude :file/path files"}})
|
|
|
|
(defn -main [args]
|
|
(let [{options :opts args' :args} (cli/parse-args args {:spec spec})
|
|
graph-dir (first args')
|
|
_ (when (or (nil? graph-dir) (:help options))
|
|
(println (str "Usage: $0 GRAPH-NAME [& ARGS] [OPTIONS]\nOptions:\n"
|
|
(cli/format-opts {:spec spec})))
|
|
(js/process.exit 1))
|
|
conn (apply sqlite-cli/open-db! (sqlite-cli/->open-db-args graph-dir))
|
|
export-options (dissoc options :file)
|
|
export-map (sqlite-export/build-export @conn {:export-type :graph :graph-options export-options})]
|
|
(if (:file options)
|
|
(do
|
|
(println "Exported" (count (:properties export-map)) "properties,"
|
|
(count (:properties export-map)) "classes and"
|
|
(count (:pages-and-blocks export-map)) "pages")
|
|
(fs/writeFileSync (resolve-path (:file options))
|
|
(with-out-str (pprint/pprint export-map))))
|
|
(pprint/pprint export-map))))
|
|
|
|
(when (= nbb/*file* (nbb/invoked-file))
|
|
(-main *command-line-args*))
|